VBAで文字列を取り出す複数のかっこの中の値を1クリックで集める

複数のかっこの中から文字列を取り出す

マクロでもできます。マクロの方が色々な事が出来ます。

EnjoyExcel

• 1つの文字列の中にある複数のかっこの組み合わせから文字列を抽出
• 複数のセルにある文字列の中からかっこの中の値を取り出せます

関連記事

マクロを使わずにセルに関数を直書きするパターンの記事も用意しています。

関連記事エクセル関数の組み合わせMID関数でかっこの中の文字だけ抽出

エクセル関数の組み合わせFIND＆MIDでかっこの中の文字だけ抽出

1つのセルに入力された文字の中で「かっこの中にある文字だけ取り出したい」という質問をいただきました。結論から申し上げますと「可能」です。エクセルは関数を組み合わせる事で欲しい文字列だけ取り出す事が出来ます。一緒に考えていきましょう。

www.slt-pgming-21.net

2024.09.18

動画

アウトプット

最終的にはこのような状態になります。（実在の住所ではないです）

動画の解説

ポイントは3つです。

複数のかっこの組み合わせからそれぞれ情報を取り出す

これで1つの文字列の中にある複数のかっこの組み合わせにも対応出来る様にしています。

指定のセルに前かっこと後かっこを記入する

かっこの組み合わせが悪い時はエラーを出す

文字列をメンテナンスしてから再度実行ボタンを押す事で間単にかっこの中の文字列が取り出せます。

ワークシートとコードを紹介

ワークシート

今回シートは提供しないのでシートの情報は各自で再現してください。

シートの情報

1. 実行／削除ボタン
2. セルB8に前かっこ
3. セルB9に後かっこ
4. セルC13以降に文字列
5. D～H列に抽出後の文字列を記入

各自ご用意下さい

Enjoy Excel

作業前

作業後

コード

Sub かっこの中()
'変数の定義
Dim aop As String 'an open parenthesis 前かっこ　とする
Dim acp As String 'an close parenthesis　後ろかっこ　とする
Dim cnt As Long ' count ループ用の変数
Dim nbr As String ' number 検索文字列
Dim srh As Long ' serch ループ用の変数
Dim chk1 As String 'check1 チェック用
Dim chk2 As String 'check2　チェック用
Dim olen As Long 'openlen 前かっこの位置
Dim clen As Long 'closelen 後ろかっこの位置
Dim rw As Long 'row 行番号
Dim clm As Long 'column 列番号
'**************************************************
'１、下準備と検索文字列の有無を確認
rw = Cells(Rows.Count, 3).End(xlUp).Row
clm = 4
'セルの値から前かっこと後ろかっこを認識する
aop = Cells(8, 2)
acp = Cells(9, 2)
'検索文字列の有無を確認
If rw <= 12 Then
    MsgBox "C列に文字列が居ません。確認お願いします。", vbInformation, "確認"
    Exit Sub
End If
'**************************************************
'２、検索文字列をループする
For cnt = 13 To rw
   '３、各検索文字列の文字数取得
    nbr = Len(Cells(cnt, 3))
    
    '文字列を1文字ずつループ
    For srh = 1 To nbr
    
        '４、前かっこを探して変数chk1にtを記入後変数olenに前かっこの位置を代入
        If Mid(Cells(cnt, 3), srh, 1) = aop Then
            chk1 = "t"  'True　の　t　を意味しています
            olen = srh
        End If
        
        '５、後ろかっこを探して変数chk2にtを記入後変数clenに後ろかっこの位置を代入
        If Mid(Cells(cnt, 3), srh, 1) = acp Then
            chk2 = "t"  'True　の　t　を意味しています
            clen = srh
            
            '６、chk1とchk2にtが記入されている時はかっこ内の値をセルに書き出す
            If chk1 = "t" And chk2 = "t" Then
                Cells(cnt, clm) = Mid(Cells(cnt, 3), olen + 1, (clen - olen) - 1)
                clm = clm + 1
                chk1 = ""
                chk2 = ""
                olen = 0
                clen = 0
            Else
                '前かっこが検出されず後ろかっこが検出されたらメッセージボックスを展開
                MsgBox cnt & "行目の文字列は前かっこと後ろかっこの数が合わないようです。 " _
                & vbCrLf & "C列の文字列を確認後再度実行ボタンを押下してください。" _
                , vbInformation, "確認"
                Exit Sub
            End If
            
        End If
    Next
'変数clmを初期値の4に戻す
clm = 4
Next
'**************************************************
End Sub

Sub 値の削除()
Dim rw As Long 'row 行番号
rw = Cells(Rows.Count, 3).End(xlUp).Row
Range(Cells(13, 4), Cells(rw, 8)).ClearContents
End Sub

関数

Len関数とMid関数を使用しています。

Len関数

指定した文字列や変数の文字数を返します。

引数のStringは必ず指定します。文字列or文字列型の変数を指定しましょう。

使用例

引数として与えた文字列の文字数が返ってきます。

Mid関数

指定した文字列から文字を取り出します。指定方法を説明します。

引数は3つです。length以外は必須です。

Lengthを省略すると開始位置から後ろ全ての文字列が抽出されます。

使用例

コードの解説

まずは要点だけ書き出します。

1、下準備と検索文字列の有無を確認

関連記事VBA-6Cellsプロパティを使ってシートの最終行と列を取得する

2、検索文字列をループする

3、各検索文字列の文字数取得

4、前かっこへの処理

5、後ろかっこへの処理

6、chk1とchk2のチェック

まとめ

EnjoyExcel